# Process GRI (Griffin Format) file to get ORBIT
# Last change: Aug 6, 2001
# Result: s1|1|2.2220|0.0018|49983.7855|0.0048|0|0.0||0.0||28.63|0.59|||3.70|0.36|0.84||11||1997A&AS..121...76T|TOK|PUB
BEGIN{  OFS="|"; FS=" "; sn=0; status="PUB"; Bibcode="";Code=""; 
 P=""; eP=""; T0=""; eT0="";Tflag="0";e="";ee="";
         omega="";eomega="";K1="";eK1="";K2="";eK2="";        
         V0="";eV0="";rms1="";rms2="";n1="";n2="";grade=""; 
         OFMT="%.8g"; Noteflag=0; }
{ 
#$0=  substr($0,0,length-1); # Remove line feed characters
if (substr($0,1,1)=="#") {$0=""}; # ignore comment lines
 if ($1=="Notes") {Noteflag=1}
 if ($1=="EndNotes") {Noteflag=0}
 if ((($1=="System")||($1=="End"))&&(Noteflag==0)) {
     if (sn>0) { #Print the previous system 
	 print "s"sn,Orbit,P,eP,T0,eT0,Tflag,e,ee,omega,eomega,K1,eK1,K2,eK2,V0,eV0,rms1,rms2,n1,n2,grade,Bibcode,Code,status }
	 sn=$2;
	 P=""; eP=""; T0=""; eT0="";Tflag="0";e="";ee="";
         omega="";eomega="";K1="";eK1="";K2="";eK2="";        
         V0="";eV0="";rms1="";rms2="";n1="";n2="";grade="";}
 if (Noteflag==0) {
      if ($1=="System") sn=$2
      if ($1=="Bibcode") Bibcode=$2
      if ($1=="Code") Code=$2
      if ($1=="Orbit") Orbit=$2
      if ($1=="P") {P=$2; eP=$3;}
      if (($1=="T")||($1=="T0")) {T0=$2; eT0=$3; 
       if (T0<9000){ # Convert years to JD
           CONVFMT="%.3f";
	   T0 = 365.25*(T0-1986)+46431.5 ""; eT0=eT0*365.25 ""; 
	   P=365.25*P ""; eP=365.25*eP "";
       } 
      }
      if ($1=="Tflag") {Tflag=$2;}
      if ($1=="e") {e=$2; ee=$3;}
      if (($1=="w")||($1=="omega"))  {omega=$2; eomega=$3;}
      if ($1=="K1") {K1=$2; eK1=$3;}
      if ($1=="K2") {K2=$2; eK2=$3;}
      if ($1=="V0") {V0=$2; eV0=$3;}
      if ($1=="rms1") rms1=$2
      if ($1=="rms2") rms2=$2
       if ($1=="n1") n1=$2
      if ($1=="n2") n2=$2
      if ($1=="grade") grade=$2 
			   }
			   }